home *** CD-ROM | disk | FTP | other *** search
/ MacWorld 1999 January - Disc 2 / Macworld (1999-01) (Disk 2).dmg / Mac OS 8.5 Updaters / RealPC⁄Soft Windows / RealPC / RealPC Upgrade Disk / INSIGNIA / COPYWINF.BAT < prev    next >
Encoding:
DOS Batch File  |  1998-08-24  |  1.8 KB  |  65 lines
  1. rem [
  2. rem    Name:        u.copywinf.bat
  3. rem
  4. rem    Derived from:    (original)
  5. rem
  6. rem    Author:        Clive Standbridge
  7. rem
  8. rem    Created on:    Nov 1996
  9. rem
  10. rem    Sccs ID:    @(#)u.copywinf.bat    1.4 05/07/97
  11. rem
  12. rem    Coding Stds:    3.0
  13. rem
  14. rem    Purpose:    To copy files to the appropriate directory when
  15. rem            upgrading a split Windows 3.1 setup.
  16. rem
  17. rem    Parameters:    1    Directory containing files to be copied
  18. rem            2    FSA directory for split Windows setup.
  19. rem                 = c:\windows for hard disk only setup.
  20. rem
  21. rem    Copyright 1997 Insignia Solutions PLC. All rights reserved.
  22. rem ]
  23.  
  24. rem Sanity check source directory
  25. if not exist %1\nul goto end
  26.  
  27. rem Change drive and directory to find source files
  28. rem (the set commands allocate env. space)
  29. set copywinf_drive=__
  30. set copywinf_colon=_
  31. ibatch copywinf_drive string %1 0 2
  32. ibatch copywinf_colon string %1 1 1
  33. if "%copywinf_colon%" == ":" %copywinf_drive%
  34. cd %1
  35.  
  36. rem Skip if not a split setup
  37. rem Get (possibly FSA) Windows directory in known case and test it
  38. rem (the set command allocates env. space)
  39. set copywinf_windir=%2
  40. ibatch copywinf_windir tolower %2
  41. if "%copywinf_windir%" == "c:\windows" goto c_only
  42.  
  43. rem ===========
  44. rem Split setup
  45. rem ===========
  46. rem Update existing files in the FSA directory
  47. for %%f in (*.*) do if exist %2\%%f copy %%f %2 /Y    >>c:\insignia\up.log
  48.  
  49. rem Update existing files in the c:\windows directory
  50. for %%f in (*.*) do if exist c:\windows\%%f copy %%f c:\windows /Y    >>c:\insignia\up.log
  51.  
  52. rem Copy new files to the c:\windows directory
  53. for %%f in (*.*) do if NOT exist c:\windows\%%f if NOT exist %2\%%f copy %%f c:\windows /Y    >>c:\insignia\up.log
  54.  
  55. goto end
  56.  
  57. :c_only
  58. rem ========================================
  59. rem Hard disk only setup - this case is easy
  60. rem ========================================
  61. if exist *.* copy *.* %2 /Y    >>c:\insignia\up.log
  62. goto end
  63.  
  64. :end
  65.